1%{
2/*
3   +----------------------------------------------------------------------+
4   | Zend Engine                                                          |
5   +----------------------------------------------------------------------+
6   | Copyright (c) 1998-2016 Zend Technologies Ltd. (http://www.zend.com) |
7   +----------------------------------------------------------------------+
8   | This source file is subject to version 2.00 of the Zend license,     |
9   | that is bundled with this package in the file LICENSE, and is        |
10   | available through the world-wide-web at the following url:           |
11   | http://www.zend.com/license/2_00.txt.                                |
12   | If you did not receive a copy of the Zend license and are unable to  |
13   | obtain it through the world-wide-web, please send a note to          |
14   | license@zend.com so we can mail you a copy immediately.              |
15   +----------------------------------------------------------------------+
16   | Authors: Andi Gutmans <andi@zend.com>                                |
17   |          Zeev Suraski <zeev@zend.com>                                |
18   |          Nikita Popov <nikic@php.net>                                |
19   +----------------------------------------------------------------------+
20*/
21
22/* $Id$ */
23
24#include "zend_compile.h"
25#include "zend.h"
26#include "zend_list.h"
27#include "zend_globals.h"
28#include "zend_API.h"
29#include "zend_constants.h"
30#include "zend_language_scanner.h"
31
32#define YYSIZE_T size_t
33#define yytnamerr zend_yytnamerr
34static YYSIZE_T zend_yytnamerr(char*, const char*);
35
36#define YYERROR_VERBOSE
37#define YYSTYPE zend_parser_stack_elem
38
39#ifdef _MSC_VER
40#define YYMALLOC malloc
41#define YYFREE free
42#endif
43
44%}
45
46%pure_parser
47%expect 0
48
49%code requires {
50}
51
52%destructor { zend_ast_destroy($$); } <ast>
53%destructor { if ($$) zend_string_release($$); } <str>
54
55%left T_INCLUDE T_INCLUDE_ONCE T_EVAL T_REQUIRE T_REQUIRE_ONCE
56%left ','
57%left T_LOGICAL_OR
58%left T_LOGICAL_XOR
59%left T_LOGICAL_AND
60%right T_PRINT
61%right T_YIELD
62%right T_DOUBLE_ARROW
63%right T_YIELD_FROM
64%left '=' T_PLUS_EQUAL T_MINUS_EQUAL T_MUL_EQUAL T_DIV_EQUAL T_CONCAT_EQUAL T_MOD_EQUAL T_AND_EQUAL T_OR_EQUAL T_XOR_EQUAL T_SL_EQUAL T_SR_EQUAL T_POW_EQUAL
65%left '?' ':'
66%right T_COALESCE
67%left T_BOOLEAN_OR
68%left T_BOOLEAN_AND
69%left '|'
70%left '^'
71%left '&'
72%nonassoc T_IS_EQUAL T_IS_NOT_EQUAL T_IS_IDENTICAL T_IS_NOT_IDENTICAL T_SPACESHIP
73%nonassoc '<' T_IS_SMALLER_OR_EQUAL '>' T_IS_GREATER_OR_EQUAL
74%left T_SL T_SR
75%left '+' '-' '.'
76%left '*' '/' '%'
77%right '!'
78%nonassoc T_INSTANCEOF
79%right '~' T_INC T_DEC T_INT_CAST T_DOUBLE_CAST T_STRING_CAST T_ARRAY_CAST T_OBJECT_CAST T_BOOL_CAST T_UNSET_CAST '@'
80%right T_POW
81%right '['
82%nonassoc T_NEW T_CLONE
83%left T_NOELSE
84%left T_ELSEIF
85%left T_ELSE
86%left T_ENDIF
87%right T_STATIC T_ABSTRACT T_FINAL T_PRIVATE T_PROTECTED T_PUBLIC
88
89%token <ast> T_LNUMBER   "integer number (T_LNUMBER)"
90%token <ast> T_DNUMBER   "floating-point number (T_DNUMBER)"
91%token <ast> T_STRING    "identifier (T_STRING)"
92%token <ast> T_VARIABLE  "variable (T_VARIABLE)"
93%token <ast> T_INLINE_HTML
94%token <ast> T_ENCAPSED_AND_WHITESPACE  "quoted-string and whitespace (T_ENCAPSED_AND_WHITESPACE)"
95%token <ast> T_CONSTANT_ENCAPSED_STRING "quoted-string (T_CONSTANT_ENCAPSED_STRING)"
96%token <ast> T_STRING_VARNAME "variable name (T_STRING_VARNAME)"
97%token <ast> T_NUM_STRING "number (T_NUM_STRING)"
98
99%token END 0 "end of file"
100%token T_INCLUDE      "include (T_INCLUDE)"
101%token T_INCLUDE_ONCE "include_once (T_INCLUDE_ONCE)"
102%token T_EVAL         "eval (T_EVAL)"
103%token T_REQUIRE      "require (T_REQUIRE)"
104%token T_REQUIRE_ONCE "require_once (T_REQUIRE_ONCE)"
105%token T_LOGICAL_OR   "or (T_LOGICAL_OR)"
106%token T_LOGICAL_XOR  "xor (T_LOGICAL_XOR)"
107%token T_LOGICAL_AND  "and (T_LOGICAL_AND)"
108%token T_PRINT        "print (T_PRINT)"
109%token T_YIELD        "yield (T_YIELD)"
110%token T_YIELD_FROM   "yield from (T_YIELD_FROM)"
111%token T_PLUS_EQUAL   "+= (T_PLUS_EQUAL)"
112%token T_MINUS_EQUAL  "-= (T_MINUS_EQUAL)"
113%token T_MUL_EQUAL    "*= (T_MUL_EQUAL)"
114%token T_DIV_EQUAL    "/= (T_DIV_EQUAL)"
115%token T_CONCAT_EQUAL ".= (T_CONCAT_EQUAL)"
116%token T_MOD_EQUAL    "%= (T_MOD_EQUAL)"
117%token T_AND_EQUAL    "&= (T_AND_EQUAL)"
118%token T_OR_EQUAL     "|= (T_OR_EQUAL)"
119%token T_XOR_EQUAL    "^= (T_XOR_EQUAL)"
120%token T_SL_EQUAL     "<<= (T_SL_EQUAL)"
121%token T_SR_EQUAL     ">>= (T_SR_EQUAL)"
122%token T_BOOLEAN_OR   "|| (T_BOOLEAN_OR)"
123%token T_BOOLEAN_AND  "&& (T_BOOLEAN_AND)"
124%token T_IS_EQUAL     "== (T_IS_EQUAL)"
125%token T_IS_NOT_EQUAL "!= (T_IS_NOT_EQUAL)"
126%token T_IS_IDENTICAL "=== (T_IS_IDENTICAL)"
127%token T_IS_NOT_IDENTICAL "!== (T_IS_NOT_IDENTICAL)"
128%token T_IS_SMALLER_OR_EQUAL "<= (T_IS_SMALLER_OR_EQUAL)"
129%token T_IS_GREATER_OR_EQUAL ">= (T_IS_GREATER_OR_EQUAL)"
130%token T_SPACESHIP "<=> (T_SPACESHIP)"
131%token T_SL "<< (T_SL)"
132%token T_SR ">> (T_SR)"
133%token T_INSTANCEOF  "instanceof (T_INSTANCEOF)"
134%token T_INC "++ (T_INC)"
135%token T_DEC "-- (T_DEC)"
136%token T_INT_CAST    "(int) (T_INT_CAST)"
137%token T_DOUBLE_CAST "(double) (T_DOUBLE_CAST)"
138%token T_STRING_CAST "(string) (T_STRING_CAST)"
139%token T_ARRAY_CAST  "(array) (T_ARRAY_CAST)"
140%token T_OBJECT_CAST "(object) (T_OBJECT_CAST)"
141%token T_BOOL_CAST   "(bool) (T_BOOL_CAST)"
142%token T_UNSET_CAST  "(unset) (T_UNSET_CAST)"
143%token T_NEW       "new (T_NEW)"
144%token T_CLONE     "clone (T_CLONE)"
145%token T_EXIT      "exit (T_EXIT)"
146%token T_IF        "if (T_IF)"
147%token T_ELSEIF    "elseif (T_ELSEIF)"
148%token T_ELSE      "else (T_ELSE)"
149%token T_ENDIF     "endif (T_ENDIF)"
150%token T_ECHO       "echo (T_ECHO)"
151%token T_DO         "do (T_DO)"
152%token T_WHILE      "while (T_WHILE)"
153%token T_ENDWHILE   "endwhile (T_ENDWHILE)"
154%token T_FOR        "for (T_FOR)"
155%token T_ENDFOR     "endfor (T_ENDFOR)"
156%token T_FOREACH    "foreach (T_FOREACH)"
157%token T_ENDFOREACH "endforeach (T_ENDFOREACH)"
158%token T_DECLARE    "declare (T_DECLARE)"
159%token T_ENDDECLARE "enddeclare (T_ENDDECLARE)"
160%token T_AS         "as (T_AS)"
161%token T_SWITCH     "switch (T_SWITCH)"
162%token T_ENDSWITCH  "endswitch (T_ENDSWITCH)"
163%token T_CASE       "case (T_CASE)"
164%token T_DEFAULT    "default (T_DEFAULT)"
165%token T_BREAK      "break (T_BREAK)"
166%token T_CONTINUE   "continue (T_CONTINUE)"
167%token T_GOTO       "goto (T_GOTO)"
168%token T_FUNCTION   "function (T_FUNCTION)"
169%token T_CONST      "const (T_CONST)"
170%token T_RETURN     "return (T_RETURN)"
171%token T_TRY        "try (T_TRY)"
172%token T_CATCH      "catch (T_CATCH)"
173%token T_FINALLY    "finally (T_FINALLY)"
174%token T_THROW      "throw (T_THROW)"
175%token T_USE        "use (T_USE)"
176%token T_INSTEADOF  "insteadof (T_INSTEADOF)"
177%token T_GLOBAL     "global (T_GLOBAL)"
178%token T_STATIC     "static (T_STATIC)"
179%token T_ABSTRACT   "abstract (T_ABSTRACT)"
180%token T_FINAL      "final (T_FINAL)"
181%token T_PRIVATE    "private (T_PRIVATE)"
182%token T_PROTECTED  "protected (T_PROTECTED)"
183%token T_PUBLIC     "public (T_PUBLIC)"
184%token T_VAR        "var (T_VAR)"
185%token T_UNSET      "unset (T_UNSET)"
186%token T_ISSET      "isset (T_ISSET)"
187%token T_EMPTY      "empty (T_EMPTY)"
188%token T_HALT_COMPILER "__halt_compiler (T_HALT_COMPILER)"
189%token T_CLASS      "class (T_CLASS)"
190%token T_TRAIT      "trait (T_TRAIT)"
191%token T_INTERFACE  "interface (T_INTERFACE)"
192%token T_EXTENDS    "extends (T_EXTENDS)"
193%token T_IMPLEMENTS "implements (T_IMPLEMENTS)"
194%token T_OBJECT_OPERATOR "-> (T_OBJECT_OPERATOR)"
195%token T_DOUBLE_ARROW    "=> (T_DOUBLE_ARROW)"
196%token T_LIST            "list (T_LIST)"
197%token T_ARRAY           "array (T_ARRAY)"
198%token T_CALLABLE        "callable (T_CALLABLE)"
199%token T_LINE            "__LINE__ (T_LINE)"
200%token T_FILE            "__FILE__ (T_FILE)"
201%token T_DIR             "__DIR__ (T_DIR)"
202%token T_CLASS_C         "__CLASS__ (T_CLASS_C)"
203%token T_TRAIT_C         "__TRAIT__ (T_TRAIT_C)"
204%token T_METHOD_C        "__METHOD__ (T_METHOD_C)"
205%token T_FUNC_C          "__FUNCTION__ (T_FUNC_C)"
206%token T_COMMENT         "comment (T_COMMENT)"
207%token T_DOC_COMMENT     "doc comment (T_DOC_COMMENT)"
208%token T_OPEN_TAG        "open tag (T_OPEN_TAG)"
209%token T_OPEN_TAG_WITH_ECHO "open tag with echo (T_OPEN_TAG_WITH_ECHO)"
210%token T_CLOSE_TAG       "close tag (T_CLOSE_TAG)"
211%token T_WHITESPACE      "whitespace (T_WHITESPACE)"
212%token T_START_HEREDOC   "heredoc start (T_START_HEREDOC)"
213%token T_END_HEREDOC     "heredoc end (T_END_HEREDOC)"
214%token T_DOLLAR_OPEN_CURLY_BRACES "${ (T_DOLLAR_OPEN_CURLY_BRACES)"
215%token T_CURLY_OPEN      "{$ (T_CURLY_OPEN)"
216%token T_PAAMAYIM_NEKUDOTAYIM ":: (T_PAAMAYIM_NEKUDOTAYIM)"
217%token T_NAMESPACE       "namespace (T_NAMESPACE)"
218%token T_NS_C            "__NAMESPACE__ (T_NS_C)"
219%token T_NS_SEPARATOR    "\\ (T_NS_SEPARATOR)"
220%token T_ELLIPSIS        "... (T_ELLIPSIS)"
221%token T_COALESCE        "?? (T_COALESCE)"
222%token T_POW             "** (T_POW)"
223%token T_POW_EQUAL       "**= (T_POW_EQUAL)"
224
225/* Token used to force a parse error from the lexer */
226%token T_ERROR
227
228%type <ast> top_statement namespace_name name statement function_declaration_statement
229%type <ast> class_declaration_statement trait_declaration_statement
230%type <ast> interface_declaration_statement interface_extends_list
231%type <ast> group_use_declaration inline_use_declarations inline_use_declaration
232%type <ast> mixed_group_use_declaration use_declaration unprefixed_use_declaration
233%type <ast> unprefixed_use_declarations const_decl inner_statement
234%type <ast> expr optional_expr while_statement for_statement foreach_variable
235%type <ast> foreach_statement declare_statement finally_statement unset_variable variable
236%type <ast> extends_from parameter optional_type argument expr_without_variable global_var
237%type <ast> static_var class_statement trait_adaptation trait_precedence trait_alias
238%type <ast> absolute_trait_method_reference trait_method_reference property echo_expr
239%type <ast> new_expr anonymous_class class_name class_name_reference simple_variable
240%type <ast> internal_functions_in_yacc
241%type <ast> exit_expr scalar backticks_expr lexical_var function_call member_name property_name
242%type <ast> variable_class_name dereferencable_scalar constant dereferencable
243%type <ast> callable_expr callable_variable static_member new_variable
244%type <ast> encaps_var encaps_var_offset isset_variables
245%type <ast> top_statement_list use_declarations const_list inner_statement_list if_stmt
246%type <ast> alt_if_stmt for_exprs switch_case_list global_var_list static_var_list
247%type <ast> echo_expr_list unset_variables catch_name_list catch_list parameter_list class_statement_list
248%type <ast> implements_list case_list if_stmt_without_else
249%type <ast> non_empty_parameter_list argument_list non_empty_argument_list property_list
250%type <ast> class_const_list class_const_decl name_list trait_adaptations method_body non_empty_for_exprs
251%type <ast> ctor_arguments alt_if_stmt_without_else trait_adaptation_list lexical_vars
252%type <ast> lexical_var_list encaps_list
253%type <ast> array_pair non_empty_array_pair_list array_pair_list
254%type <ast> isset_variable type return_type type_expr
255%type <ast> identifier
256
257%type <num> returns_ref function is_reference is_variadic variable_modifiers
258%type <num> method_modifiers non_empty_member_modifiers member_modifier
259%type <num> class_modifiers class_modifier use_type backup_fn_flags
260
261%type <str> backup_doc_comment
262
263%% /* Rules */
264
265start:
266	top_statement_list	{ CG(ast) = $1; }
267;
268
269reserved_non_modifiers:
270	  T_INCLUDE | T_INCLUDE_ONCE | T_EVAL | T_REQUIRE | T_REQUIRE_ONCE | T_LOGICAL_OR | T_LOGICAL_XOR | T_LOGICAL_AND
271	| T_INSTANCEOF | T_NEW | T_CLONE | T_EXIT | T_IF | T_ELSEIF | T_ELSE | T_ENDIF | T_ECHO | T_DO | T_WHILE | T_ENDWHILE
272	| T_FOR | T_ENDFOR | T_FOREACH | T_ENDFOREACH | T_DECLARE | T_ENDDECLARE | T_AS | T_TRY | T_CATCH | T_FINALLY
273	| T_THROW | T_USE | T_INSTEADOF | T_GLOBAL | T_VAR | T_UNSET | T_ISSET | T_EMPTY | T_CONTINUE | T_GOTO
274	| T_FUNCTION | T_CONST | T_RETURN | T_PRINT | T_YIELD | T_LIST | T_SWITCH | T_ENDSWITCH | T_CASE | T_DEFAULT | T_BREAK
275	| T_ARRAY | T_CALLABLE | T_EXTENDS | T_IMPLEMENTS | T_NAMESPACE | T_TRAIT | T_INTERFACE | T_CLASS
276	| T_CLASS_C | T_TRAIT_C | T_FUNC_C | T_METHOD_C | T_LINE | T_FILE | T_DIR | T_NS_C
277;
278
279semi_reserved:
280	  reserved_non_modifiers
281	| T_STATIC | T_ABSTRACT | T_FINAL | T_PRIVATE | T_PROTECTED | T_PUBLIC
282;
283
284identifier:
285		T_STRING { $$ = $1; }
286	| 	semi_reserved  {
287			zval zv;
288			zend_lex_tstring(&zv);
289			$$ = zend_ast_create_zval(&zv);
290		}
291;
292
293top_statement_list:
294		top_statement_list top_statement { $$ = zend_ast_list_add($1, $2); }
295	|	/* empty */ { $$ = zend_ast_create_list(0, ZEND_AST_STMT_LIST); }
296;
297
298namespace_name:
299		T_STRING								{ $$ = $1; }
300	|	namespace_name T_NS_SEPARATOR T_STRING	{ $$ = zend_ast_append_str($1, $3); }
301;
302
303name:
304		namespace_name								{ $$ = $1; $$->attr = ZEND_NAME_NOT_FQ; }
305	|	T_NAMESPACE T_NS_SEPARATOR namespace_name	{ $$ = $3; $$->attr = ZEND_NAME_RELATIVE; }
306	|	T_NS_SEPARATOR namespace_name				{ $$ = $2; $$->attr = ZEND_NAME_FQ; }
307;
308
309top_statement:
310		statement							{ $$ = $1; }
311	|	function_declaration_statement		{ $$ = $1; }
312	|	class_declaration_statement			{ $$ = $1; }
313	|	trait_declaration_statement			{ $$ = $1; }
314	|	interface_declaration_statement		{ $$ = $1; }
315	|	T_HALT_COMPILER '(' ')' ';'
316			{ $$ = zend_ast_create(ZEND_AST_HALT_COMPILER,
317			      zend_ast_create_zval_from_long(zend_get_scanned_file_offset()));
318			  zend_stop_lexing(); }
319	|	T_NAMESPACE namespace_name ';'
320			{ $$ = zend_ast_create(ZEND_AST_NAMESPACE, $2, NULL);
321			  RESET_DOC_COMMENT(); }
322	|	T_NAMESPACE namespace_name { RESET_DOC_COMMENT(); }
323		'{' top_statement_list '}'
324			{ $$ = zend_ast_create(ZEND_AST_NAMESPACE, $2, $5); }
325	|	T_NAMESPACE { RESET_DOC_COMMENT(); }
326		'{' top_statement_list '}'
327			{ $$ = zend_ast_create(ZEND_AST_NAMESPACE, NULL, $4); }
328	|	T_USE mixed_group_use_declaration ';'		{ $$ = $2; }
329	|	T_USE use_type group_use_declaration ';'	{ $$ = $3; $$->attr = $2; }
330	|	T_USE use_declarations ';'					{ $$ = $2; $$->attr = T_CLASS; }
331	|	T_USE use_type use_declarations ';'			{ $$ = $3; $$->attr = $2; }
332	|	T_CONST const_list ';'						{ $$ = $2; }
333;
334
335use_type:
336	 	T_FUNCTION 		{ $$ = T_FUNCTION; }
337	| 	T_CONST 		{ $$ = T_CONST; }
338;
339
340group_use_declaration:
341		namespace_name T_NS_SEPARATOR '{' unprefixed_use_declarations '}'
342			{ $$ = zend_ast_create(ZEND_AST_GROUP_USE, $1, $4); }
343	|	T_NS_SEPARATOR namespace_name T_NS_SEPARATOR '{' unprefixed_use_declarations '}'
344			{ $$ = zend_ast_create(ZEND_AST_GROUP_USE, $2, $5); }
345;
346
347mixed_group_use_declaration:
348		namespace_name T_NS_SEPARATOR '{' inline_use_declarations '}'
349			{ $$ = zend_ast_create(ZEND_AST_GROUP_USE, $1, $4);}
350	|	T_NS_SEPARATOR namespace_name T_NS_SEPARATOR '{' inline_use_declarations '}'
351			{ $$ = zend_ast_create(ZEND_AST_GROUP_USE, $2, $5); }
352;
353
354inline_use_declarations:
355		inline_use_declarations ',' inline_use_declaration
356			{ $$ = zend_ast_list_add($1, $3); }
357	|	inline_use_declaration
358			{ $$ = zend_ast_create_list(1, ZEND_AST_USE, $1); }
359;
360
361unprefixed_use_declarations:
362		unprefixed_use_declarations ',' unprefixed_use_declaration
363			{ $$ = zend_ast_list_add($1, $3); }
364	|	unprefixed_use_declaration
365			{ $$ = zend_ast_create_list(1, ZEND_AST_USE, $1); }
366;
367
368use_declarations:
369		use_declarations ',' use_declaration
370			{ $$ = zend_ast_list_add($1, $3); }
371	|	use_declaration
372			{ $$ = zend_ast_create_list(1, ZEND_AST_USE, $1); }
373;
374
375inline_use_declaration:
376		unprefixed_use_declaration { $$ = $1; $$->attr = T_CLASS; }
377	|	use_type unprefixed_use_declaration { $$ = $2; $$->attr = $1; }
378;
379
380unprefixed_use_declaration:
381		namespace_name
382			{ $$ = zend_ast_create(ZEND_AST_USE_ELEM, $1, NULL); }
383	|	namespace_name T_AS T_STRING
384			{ $$ = zend_ast_create(ZEND_AST_USE_ELEM, $1, $3); }
385;
386
387use_declaration:
388		unprefixed_use_declaration                { $$ = $1; }
389	|	T_NS_SEPARATOR unprefixed_use_declaration { $$ = $2; }
390;
391
392const_list:
393		const_list ',' const_decl { $$ = zend_ast_list_add($1, $3); }
394	|	const_decl { $$ = zend_ast_create_list(1, ZEND_AST_CONST_DECL, $1); }
395;
396
397inner_statement_list:
398		inner_statement_list inner_statement
399			{ $$ = zend_ast_list_add($1, $2); }
400	|	/* empty */
401			{ $$ = zend_ast_create_list(0, ZEND_AST_STMT_LIST); }
402;
403
404
405inner_statement:
406		statement { $$ = $1; }
407	|	function_declaration_statement 		{ $$ = $1; }
408	|	class_declaration_statement 		{ $$ = $1; }
409	|	trait_declaration_statement			{ $$ = $1; }
410	|	interface_declaration_statement		{ $$ = $1; }
411	|	T_HALT_COMPILER '(' ')' ';'
412			{ $$ = NULL; zend_error_noreturn(E_COMPILE_ERROR,
413			      "__HALT_COMPILER() can only be used from the outermost scope"); }
414;
415
416
417statement:
418		'{' inner_statement_list '}' { $$ = $2; }
419	|	if_stmt { $$ = $1; }
420	|	alt_if_stmt { $$ = $1; }
421	|	T_WHILE '(' expr ')' while_statement
422			{ $$ = zend_ast_create(ZEND_AST_WHILE, $3, $5); }
423	|	T_DO statement T_WHILE '(' expr ')' ';'
424			{ $$ = zend_ast_create(ZEND_AST_DO_WHILE, $2, $5); }
425	|	T_FOR '(' for_exprs ';' for_exprs ';' for_exprs ')' for_statement
426			{ $$ = zend_ast_create(ZEND_AST_FOR, $3, $5, $7, $9); }
427	|	T_SWITCH '(' expr ')' switch_case_list
428			{ $$ = zend_ast_create(ZEND_AST_SWITCH, $3, $5); }
429	|	T_BREAK optional_expr ';'		{ $$ = zend_ast_create(ZEND_AST_BREAK, $2); }
430	|	T_CONTINUE optional_expr ';'	{ $$ = zend_ast_create(ZEND_AST_CONTINUE, $2); }
431	|	T_RETURN optional_expr ';'		{ $$ = zend_ast_create(ZEND_AST_RETURN, $2); }
432	|	T_GLOBAL global_var_list ';'	{ $$ = $2; }
433	|	T_STATIC static_var_list ';'	{ $$ = $2; }
434	|	T_ECHO echo_expr_list ';'		{ $$ = $2; }
435	|	T_INLINE_HTML { $$ = zend_ast_create(ZEND_AST_ECHO, $1); }
436	|	expr ';' { $$ = $1; }
437	|	T_UNSET '(' unset_variables ')' ';' { $$ = $3; }
438	|	T_FOREACH '(' expr T_AS foreach_variable ')' foreach_statement
439			{ $$ = zend_ast_create(ZEND_AST_FOREACH, $3, $5, NULL, $7); }
440	|	T_FOREACH '(' expr T_AS foreach_variable T_DOUBLE_ARROW foreach_variable ')'
441		foreach_statement
442			{ $$ = zend_ast_create(ZEND_AST_FOREACH, $3, $7, $5, $9); }
443	|	T_DECLARE '(' const_list ')'
444			{ zend_handle_encoding_declaration($3); }
445		declare_statement
446			{ $$ = zend_ast_create(ZEND_AST_DECLARE, $3, $6); }
447	|	';'	/* empty statement */ { $$ = NULL; }
448	|	T_TRY '{' inner_statement_list '}' catch_list finally_statement
449			{ $$ = zend_ast_create(ZEND_AST_TRY, $3, $5, $6); }
450	|	T_THROW expr ';' { $$ = zend_ast_create(ZEND_AST_THROW, $2); }
451	|	T_GOTO T_STRING ';' { $$ = zend_ast_create(ZEND_AST_GOTO, $2); }
452	|	T_STRING ':' { $$ = zend_ast_create(ZEND_AST_LABEL, $1); }
453;
454
455catch_list:
456		/* empty */
457			{ $$ = zend_ast_create_list(0, ZEND_AST_CATCH_LIST); }
458	|	catch_list T_CATCH '(' catch_name_list T_VARIABLE ')' '{' inner_statement_list '}'
459			{ $$ = zend_ast_list_add($1, zend_ast_create(ZEND_AST_CATCH, $4, $5, $8)); }
460;
461
462catch_name_list:
463		name { $$ = zend_ast_create_list(1, ZEND_AST_NAME_LIST, $1); }
464	|	catch_name_list '|' name { $$ = zend_ast_list_add($1, $3); }
465;
466
467finally_statement:
468		/* empty */ { $$ = NULL; }
469	|	T_FINALLY '{' inner_statement_list '}' { $$ = $3; }
470;
471
472unset_variables:
473		unset_variable { $$ = zend_ast_create_list(1, ZEND_AST_STMT_LIST, $1); }
474	|	unset_variables ',' unset_variable { $$ = zend_ast_list_add($1, $3); }
475;
476
477unset_variable:
478		variable { $$ = zend_ast_create(ZEND_AST_UNSET, $1); }
479;
480
481function_declaration_statement:
482	function returns_ref T_STRING backup_doc_comment '(' parameter_list ')' return_type
483	backup_fn_flags '{' inner_statement_list '}' backup_fn_flags
484		{ $$ = zend_ast_create_decl(ZEND_AST_FUNC_DECL, $2 | $13, $1, $4,
485		      zend_ast_get_str($3), $6, NULL, $11, $8); CG(extra_fn_flags) = $9; }
486;
487
488is_reference:
489		/* empty */	{ $$ = 0; }
490	|	'&'			{ $$ = ZEND_PARAM_REF; }
491;
492
493is_variadic:
494		/* empty */ { $$ = 0; }
495	|	T_ELLIPSIS  { $$ = ZEND_PARAM_VARIADIC; }
496;
497
498class_declaration_statement:
499		class_modifiers T_CLASS { $<num>$ = CG(zend_lineno); }
500		T_STRING extends_from implements_list backup_doc_comment '{' class_statement_list '}'
501			{ $$ = zend_ast_create_decl(ZEND_AST_CLASS, $1, $<num>3, $7, zend_ast_get_str($4), $5, $6, $9, NULL); }
502	|	T_CLASS { $<num>$ = CG(zend_lineno); }
503		T_STRING extends_from implements_list backup_doc_comment '{' class_statement_list '}'
504			{ $$ = zend_ast_create_decl(ZEND_AST_CLASS, 0, $<num>2, $6, zend_ast_get_str($3), $4, $5, $8, NULL); }
505;
506
507class_modifiers:
508		class_modifier 					{ $$ = $1; }
509	|	class_modifiers class_modifier 	{ $$ = zend_add_class_modifier($1, $2); }
510;
511
512class_modifier:
513		T_ABSTRACT 		{ $$ = ZEND_ACC_EXPLICIT_ABSTRACT_CLASS; }
514	|	T_FINAL 		{ $$ = ZEND_ACC_FINAL; }
515;
516
517trait_declaration_statement:
518		T_TRAIT { $<num>$ = CG(zend_lineno); }
519		T_STRING backup_doc_comment '{' class_statement_list '}'
520			{ $$ = zend_ast_create_decl(ZEND_AST_CLASS, ZEND_ACC_TRAIT, $<num>2, $4, zend_ast_get_str($3), NULL, NULL, $6, NULL); }
521;
522
523interface_declaration_statement:
524		T_INTERFACE { $<num>$ = CG(zend_lineno); }
525		T_STRING interface_extends_list backup_doc_comment '{' class_statement_list '}'
526			{ $$ = zend_ast_create_decl(ZEND_AST_CLASS, ZEND_ACC_INTERFACE, $<num>2, $5, zend_ast_get_str($3), NULL, $4, $7, NULL); }
527;
528
529extends_from:
530		/* empty */		{ $$ = NULL; }
531	|	T_EXTENDS name	{ $$ = $2; }
532;
533
534interface_extends_list:
535		/* empty */			{ $$ = NULL; }
536	|	T_EXTENDS name_list	{ $$ = $2; }
537;
538
539implements_list:
540		/* empty */				{ $$ = NULL; }
541	|	T_IMPLEMENTS name_list	{ $$ = $2; }
542;
543
544foreach_variable:
545		variable			{ $$ = $1; }
546	|	'&' variable		{ $$ = zend_ast_create(ZEND_AST_REF, $2); }
547	|	T_LIST '(' array_pair_list ')' { $3->attr = 1; $$ = $3; }
548	|	'[' array_pair_list ']' { $$ = $2; }
549;
550
551for_statement:
552		statement { $$ = $1; }
553	|	':' inner_statement_list T_ENDFOR ';' { $$ = $2; }
554;
555
556foreach_statement:
557		statement { $$ = $1; }
558	|	':' inner_statement_list T_ENDFOREACH ';' { $$ = $2; }
559;
560
561declare_statement:
562		statement { $$ = $1; }
563	|	':' inner_statement_list T_ENDDECLARE ';' { $$ = $2; }
564;
565
566switch_case_list:
567		'{' case_list '}'					{ $$ = $2; }
568	|	'{' ';' case_list '}'				{ $$ = $3; }
569	|	':' case_list T_ENDSWITCH ';'		{ $$ = $2; }
570	|	':' ';' case_list T_ENDSWITCH ';'	{ $$ = $3; }
571;
572
573case_list:
574		/* empty */ { $$ = zend_ast_create_list(0, ZEND_AST_SWITCH_LIST); }
575	|	case_list T_CASE expr case_separator inner_statement_list
576			{ $$ = zend_ast_list_add($1, zend_ast_create(ZEND_AST_SWITCH_CASE, $3, $5)); }
577	|	case_list T_DEFAULT case_separator inner_statement_list
578			{ $$ = zend_ast_list_add($1, zend_ast_create(ZEND_AST_SWITCH_CASE, NULL, $4)); }
579;
580
581case_separator:
582		':'
583	|	';'
584;
585
586
587while_statement:
588		statement { $$ = $1; }
589	|	':' inner_statement_list T_ENDWHILE ';' { $$ = $2; }
590;
591
592
593if_stmt_without_else:
594		T_IF '(' expr ')' statement
595			{ $$ = zend_ast_create_list(1, ZEND_AST_IF,
596			      zend_ast_create(ZEND_AST_IF_ELEM, $3, $5)); }
597	|	if_stmt_without_else T_ELSEIF '(' expr ')' statement
598			{ $$ = zend_ast_list_add($1,
599			      zend_ast_create(ZEND_AST_IF_ELEM, $4, $6)); }
600;
601
602if_stmt:
603		if_stmt_without_else %prec T_NOELSE { $$ = $1; }
604	|	if_stmt_without_else T_ELSE statement
605			{ $$ = zend_ast_list_add($1, zend_ast_create(ZEND_AST_IF_ELEM, NULL, $3)); }
606;
607
608alt_if_stmt_without_else:
609		T_IF '(' expr ')' ':' inner_statement_list
610			{ $$ = zend_ast_create_list(1, ZEND_AST_IF,
611			      zend_ast_create(ZEND_AST_IF_ELEM, $3, $6)); }
612	|	alt_if_stmt_without_else T_ELSEIF '(' expr ')' ':' inner_statement_list
613			{ $$ = zend_ast_list_add($1,
614			      zend_ast_create(ZEND_AST_IF_ELEM, $4, $7)); }
615;
616
617alt_if_stmt:
618		alt_if_stmt_without_else T_ENDIF ';' { $$ = $1; }
619	|	alt_if_stmt_without_else T_ELSE ':' inner_statement_list T_ENDIF ';'
620			{ $$ = zend_ast_list_add($1,
621			      zend_ast_create(ZEND_AST_IF_ELEM, NULL, $4)); }
622;
623
624parameter_list:
625		non_empty_parameter_list { $$ = $1; }
626	|	/* empty */	{ $$ = zend_ast_create_list(0, ZEND_AST_PARAM_LIST); }
627;
628
629
630non_empty_parameter_list:
631		parameter
632			{ $$ = zend_ast_create_list(1, ZEND_AST_PARAM_LIST, $1); }
633	|	non_empty_parameter_list ',' parameter
634			{ $$ = zend_ast_list_add($1, $3); }
635;
636
637parameter:
638		optional_type is_reference is_variadic T_VARIABLE
639			{ $$ = zend_ast_create_ex(ZEND_AST_PARAM, $2 | $3, $1, $4, NULL); }
640	|	optional_type is_reference is_variadic T_VARIABLE '=' expr
641			{ $$ = zend_ast_create_ex(ZEND_AST_PARAM, $2 | $3, $1, $4, $6); }
642;
643
644
645optional_type:
646		/* empty */	{ $$ = NULL; }
647	|	type_expr	{ $$ = $1; }
648;
649
650type_expr:
651		type		{ $$ = $1; }
652	|	'?' type	{ $$ = $2; $$->attr |= ZEND_TYPE_NULLABLE; }
653;
654
655type:
656		T_ARRAY		{ $$ = zend_ast_create_ex(ZEND_AST_TYPE, IS_ARRAY); }
657	|	T_CALLABLE	{ $$ = zend_ast_create_ex(ZEND_AST_TYPE, IS_CALLABLE); }
658	|	name		{ $$ = $1; }
659;
660
661return_type:
662		/* empty */	{ $$ = NULL; }
663	|	':' type_expr	{ $$ = $2; }
664;
665
666argument_list:
667		'(' ')'	{ $$ = zend_ast_create_list(0, ZEND_AST_ARG_LIST); }
668	|	'(' non_empty_argument_list ')' { $$ = $2; }
669;
670
671non_empty_argument_list:
672		argument
673			{ $$ = zend_ast_create_list(1, ZEND_AST_ARG_LIST, $1); }
674	|	non_empty_argument_list ',' argument
675			{ $$ = zend_ast_list_add($1, $3); }
676;
677
678argument:
679		expr			{ $$ = $1; }
680	|	T_ELLIPSIS expr	{ $$ = zend_ast_create(ZEND_AST_UNPACK, $2); }
681;
682
683global_var_list:
684		global_var_list ',' global_var { $$ = zend_ast_list_add($1, $3); }
685	|	global_var { $$ = zend_ast_create_list(1, ZEND_AST_STMT_LIST, $1); }
686;
687
688global_var:
689	simple_variable
690		{ $$ = zend_ast_create(ZEND_AST_GLOBAL, zend_ast_create(ZEND_AST_VAR, $1)); }
691;
692
693
694static_var_list:
695		static_var_list ',' static_var { $$ = zend_ast_list_add($1, $3); }
696	|	static_var { $$ = zend_ast_create_list(1, ZEND_AST_STMT_LIST, $1); }
697;
698
699static_var:
700		T_VARIABLE			{ $$ = zend_ast_create(ZEND_AST_STATIC, $1, NULL); }
701	|	T_VARIABLE '=' expr	{ $$ = zend_ast_create(ZEND_AST_STATIC, $1, $3); }
702;
703
704
705class_statement_list:
706		class_statement_list class_statement
707			{ $$ = zend_ast_list_add($1, $2); }
708	|	/* empty */
709			{ $$ = zend_ast_create_list(0, ZEND_AST_STMT_LIST); }
710;
711
712
713class_statement:
714		variable_modifiers property_list ';'
715			{ $$ = $2; $$->attr = $1; }
716	|	method_modifiers T_CONST class_const_list ';'
717			{ $$ = $3; $$->attr = $1; }
718	|	T_USE name_list trait_adaptations
719			{ $$ = zend_ast_create(ZEND_AST_USE_TRAIT, $2, $3); }
720	|	method_modifiers function returns_ref identifier backup_doc_comment '(' parameter_list ')'
721		return_type backup_fn_flags method_body backup_fn_flags
722			{ $$ = zend_ast_create_decl(ZEND_AST_METHOD, $3 | $1 | $12, $2, $5,
723				  zend_ast_get_str($4), $7, NULL, $11, $9); CG(extra_fn_flags) = $10; }
724;
725
726name_list:
727		name { $$ = zend_ast_create_list(1, ZEND_AST_NAME_LIST, $1); }
728	|	name_list ',' name { $$ = zend_ast_list_add($1, $3); }
729;
730
731trait_adaptations:
732		';'								{ $$ = NULL; }
733	|	'{' '}'							{ $$ = NULL; }
734	|	'{' trait_adaptation_list '}'	{ $$ = $2; }
735;
736
737trait_adaptation_list:
738		trait_adaptation
739			{ $$ = zend_ast_create_list(1, ZEND_AST_TRAIT_ADAPTATIONS, $1); }
740	|	trait_adaptation_list trait_adaptation
741			{ $$ = zend_ast_list_add($1, $2); }
742;
743
744trait_adaptation:
745		trait_precedence ';'	{ $$ = $1; }
746	|	trait_alias ';'			{ $$ = $1; }
747;
748
749trait_precedence:
750	absolute_trait_method_reference T_INSTEADOF name_list
751		{ $$ = zend_ast_create(ZEND_AST_TRAIT_PRECEDENCE, $1, $3); }
752;
753
754trait_alias:
755		trait_method_reference T_AS T_STRING
756			{ $$ = zend_ast_create_ex(ZEND_AST_TRAIT_ALIAS, 0, $1, $3); }
757	|	trait_method_reference T_AS reserved_non_modifiers
758			{ zval zv; zend_lex_tstring(&zv); $$ = zend_ast_create_ex(ZEND_AST_TRAIT_ALIAS, 0, $1, zend_ast_create_zval(&zv)); }
759	|	trait_method_reference T_AS member_modifier identifier
760			{ $$ = zend_ast_create_ex(ZEND_AST_TRAIT_ALIAS, $3, $1, $4); }
761	|	trait_method_reference T_AS member_modifier
762			{ $$ = zend_ast_create_ex(ZEND_AST_TRAIT_ALIAS, $3, $1, NULL); }
763;
764
765trait_method_reference:
766		identifier
767			{ $$ = zend_ast_create(ZEND_AST_METHOD_REFERENCE, NULL, $1); }
768	|	absolute_trait_method_reference { $$ = $1; }
769;
770
771absolute_trait_method_reference:
772	name T_PAAMAYIM_NEKUDOTAYIM identifier
773		{ $$ = zend_ast_create(ZEND_AST_METHOD_REFERENCE, $1, $3); }
774;
775
776method_body:
777		';' /* abstract method */		{ $$ = NULL; }
778	|	'{' inner_statement_list '}'	{ $$ = $2; }
779;
780
781variable_modifiers:
782		non_empty_member_modifiers		{ $$ = $1; }
783	|	T_VAR							{ $$ = ZEND_ACC_PUBLIC; }
784;
785
786method_modifiers:
787		/* empty */						{ $$ = ZEND_ACC_PUBLIC; }
788	|	non_empty_member_modifiers
789			{ $$ = $1; if (!($$ & ZEND_ACC_PPP_MASK)) { $$ |= ZEND_ACC_PUBLIC; } }
790;
791
792non_empty_member_modifiers:
793		member_modifier			{ $$ = $1; }
794	|	non_empty_member_modifiers member_modifier
795			{ $$ = zend_add_member_modifier($1, $2); }
796;
797
798member_modifier:
799		T_PUBLIC				{ $$ = ZEND_ACC_PUBLIC; }
800	|	T_PROTECTED				{ $$ = ZEND_ACC_PROTECTED; }
801	|	T_PRIVATE				{ $$ = ZEND_ACC_PRIVATE; }
802	|	T_STATIC				{ $$ = ZEND_ACC_STATIC; }
803	|	T_ABSTRACT				{ $$ = ZEND_ACC_ABSTRACT; }
804	|	T_FINAL					{ $$ = ZEND_ACC_FINAL; }
805;
806
807property_list:
808		property_list ',' property { $$ = zend_ast_list_add($1, $3); }
809	|	property { $$ = zend_ast_create_list(1, ZEND_AST_PROP_DECL, $1); }
810;
811
812property:
813		T_VARIABLE backup_doc_comment
814			{ $$ = zend_ast_create(ZEND_AST_PROP_ELEM, $1, NULL, ($2 ? zend_ast_create_zval_from_str($2) : NULL)); }
815	|	T_VARIABLE '=' expr backup_doc_comment
816			{ $$ = zend_ast_create(ZEND_AST_PROP_ELEM, $1, $3, ($4 ? zend_ast_create_zval_from_str($4) : NULL)); }
817;
818
819class_const_list:
820		class_const_list ',' class_const_decl { $$ = zend_ast_list_add($1, $3); }
821	|	class_const_decl { $$ = zend_ast_create_list(1, ZEND_AST_CLASS_CONST_DECL, $1); }
822;
823
824class_const_decl:
825	identifier '=' expr backup_doc_comment { $$ = zend_ast_create(ZEND_AST_CONST_ELEM, $1, $3, ($4 ? zend_ast_create_zval_from_str($4) : NULL)); }
826;
827
828const_decl:
829	T_STRING '=' expr backup_doc_comment { $$ = zend_ast_create(ZEND_AST_CONST_ELEM, $1, $3, ($4 ? zend_ast_create_zval_from_str($4) : NULL)); }
830;
831
832echo_expr_list:
833		echo_expr_list ',' echo_expr { $$ = zend_ast_list_add($1, $3); }
834	|	echo_expr { $$ = zend_ast_create_list(1, ZEND_AST_STMT_LIST, $1); }
835;
836echo_expr:
837	expr { $$ = zend_ast_create(ZEND_AST_ECHO, $1); }
838;
839
840for_exprs:
841		/* empty */			{ $$ = NULL; }
842	|	non_empty_for_exprs	{ $$ = $1; }
843;
844
845non_empty_for_exprs:
846		non_empty_for_exprs ',' expr { $$ = zend_ast_list_add($1, $3); }
847	|	expr { $$ = zend_ast_create_list(1, ZEND_AST_EXPR_LIST, $1); }
848;
849
850anonymous_class:
851        T_CLASS { $<num>$ = CG(zend_lineno); } ctor_arguments
852		extends_from implements_list backup_doc_comment '{' class_statement_list '}' {
853			zend_ast *decl = zend_ast_create_decl(
854				ZEND_AST_CLASS, ZEND_ACC_ANON_CLASS, $<num>2, $6, NULL,
855				$4, $5, $8, NULL);
856			$$ = zend_ast_create(ZEND_AST_NEW, decl, $3);
857		}
858;
859
860new_expr:
861		T_NEW class_name_reference ctor_arguments
862			{ $$ = zend_ast_create(ZEND_AST_NEW, $2, $3); }
863	|	T_NEW anonymous_class
864			{ $$ = $2; }
865;
866
867expr_without_variable:
868		T_LIST '(' array_pair_list ')' '=' expr
869			{ $3->attr = 1; $$ = zend_ast_create(ZEND_AST_ASSIGN, $3, $6); }
870	|	'[' array_pair_list ']' '=' expr
871			{ $$ = zend_ast_create(ZEND_AST_ASSIGN, $2, $5); }
872	|	variable '=' expr
873			{ $$ = zend_ast_create(ZEND_AST_ASSIGN, $1, $3); }
874	|	variable '=' '&' variable
875			{ $$ = zend_ast_create(ZEND_AST_ASSIGN_REF, $1, $4); }
876	|	T_CLONE expr { $$ = zend_ast_create(ZEND_AST_CLONE, $2); }
877	|	variable T_PLUS_EQUAL expr
878			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_ADD, $1, $3); }
879	|	variable T_MINUS_EQUAL expr
880			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_SUB, $1, $3); }
881	|	variable T_MUL_EQUAL expr
882			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_MUL, $1, $3); }
883	|	variable T_POW_EQUAL expr
884			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_POW, $1, $3); }
885	|	variable T_DIV_EQUAL expr
886			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_DIV, $1, $3); }
887	|	variable T_CONCAT_EQUAL expr
888			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_CONCAT, $1, $3); }
889	|	variable T_MOD_EQUAL expr
890			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_MOD, $1, $3); }
891	|	variable T_AND_EQUAL expr
892			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_BW_AND, $1, $3); }
893	|	variable T_OR_EQUAL expr
894			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_BW_OR, $1, $3); }
895	|	variable T_XOR_EQUAL expr
896			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_BW_XOR, $1, $3); }
897	|	variable T_SL_EQUAL expr
898			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_SL, $1, $3); }
899	|	variable T_SR_EQUAL expr
900			{ $$ = zend_ast_create_assign_op(ZEND_ASSIGN_SR, $1, $3); }
901	|	variable T_INC { $$ = zend_ast_create(ZEND_AST_POST_INC, $1); }
902	|	T_INC variable { $$ = zend_ast_create(ZEND_AST_PRE_INC, $2); }
903	|	variable T_DEC { $$ = zend_ast_create(ZEND_AST_POST_DEC, $1); }
904	|	T_DEC variable { $$ = zend_ast_create(ZEND_AST_PRE_DEC, $2); }
905	|	expr T_BOOLEAN_OR expr
906			{ $$ = zend_ast_create(ZEND_AST_OR, $1, $3); }
907	|	expr T_BOOLEAN_AND expr
908			{ $$ = zend_ast_create(ZEND_AST_AND, $1, $3); }
909	|	expr T_LOGICAL_OR expr
910			{ $$ = zend_ast_create(ZEND_AST_OR, $1, $3); }
911	|	expr T_LOGICAL_AND expr
912			{ $$ = zend_ast_create(ZEND_AST_AND, $1, $3); }
913	|	expr T_LOGICAL_XOR expr
914			{ $$ = zend_ast_create_binary_op(ZEND_BOOL_XOR, $1, $3); }
915	|	expr '|' expr	{ $$ = zend_ast_create_binary_op(ZEND_BW_OR, $1, $3); }
916	|	expr '&' expr	{ $$ = zend_ast_create_binary_op(ZEND_BW_AND, $1, $3); }
917	|	expr '^' expr	{ $$ = zend_ast_create_binary_op(ZEND_BW_XOR, $1, $3); }
918	|	expr '.' expr 	{ $$ = zend_ast_create_binary_op(ZEND_CONCAT, $1, $3); }
919	|	expr '+' expr 	{ $$ = zend_ast_create_binary_op(ZEND_ADD, $1, $3); }
920	|	expr '-' expr 	{ $$ = zend_ast_create_binary_op(ZEND_SUB, $1, $3); }
921	|	expr '*' expr	{ $$ = zend_ast_create_binary_op(ZEND_MUL, $1, $3); }
922	|	expr T_POW expr	{ $$ = zend_ast_create_binary_op(ZEND_POW, $1, $3); }
923	|	expr '/' expr	{ $$ = zend_ast_create_binary_op(ZEND_DIV, $1, $3); }
924	|	expr '%' expr 	{ $$ = zend_ast_create_binary_op(ZEND_MOD, $1, $3); }
925	| 	expr T_SL expr	{ $$ = zend_ast_create_binary_op(ZEND_SL, $1, $3); }
926	|	expr T_SR expr	{ $$ = zend_ast_create_binary_op(ZEND_SR, $1, $3); }
927	|	'+' expr %prec T_INC { $$ = zend_ast_create(ZEND_AST_UNARY_PLUS, $2); }
928	|	'-' expr %prec T_INC { $$ = zend_ast_create(ZEND_AST_UNARY_MINUS, $2); }
929	|	'!' expr { $$ = zend_ast_create_ex(ZEND_AST_UNARY_OP, ZEND_BOOL_NOT, $2); }
930	|	'~' expr { $$ = zend_ast_create_ex(ZEND_AST_UNARY_OP, ZEND_BW_NOT, $2); }
931	|	expr T_IS_IDENTICAL expr
932			{ $$ = zend_ast_create_binary_op(ZEND_IS_IDENTICAL, $1, $3); }
933	|	expr T_IS_NOT_IDENTICAL expr
934			{ $$ = zend_ast_create_binary_op(ZEND_IS_NOT_IDENTICAL, $1, $3); }
935	|	expr T_IS_EQUAL expr
936			{ $$ = zend_ast_create_binary_op(ZEND_IS_EQUAL, $1, $3); }
937	|	expr T_IS_NOT_EQUAL expr
938			{ $$ = zend_ast_create_binary_op(ZEND_IS_NOT_EQUAL, $1, $3); }
939	|	expr '<' expr
940			{ $$ = zend_ast_create_binary_op(ZEND_IS_SMALLER, $1, $3); }
941	|	expr T_IS_SMALLER_OR_EQUAL expr
942			{ $$ = zend_ast_create_binary_op(ZEND_IS_SMALLER_OR_EQUAL, $1, $3); }
943	|	expr '>' expr
944			{ $$ = zend_ast_create(ZEND_AST_GREATER, $1, $3); }
945	|	expr T_IS_GREATER_OR_EQUAL expr
946			{ $$ = zend_ast_create(ZEND_AST_GREATER_EQUAL, $1, $3); }
947	|	expr T_SPACESHIP expr
948			{ $$ = zend_ast_create_binary_op(ZEND_SPACESHIP, $1, $3); }
949	|	expr T_INSTANCEOF class_name_reference
950			{ $$ = zend_ast_create(ZEND_AST_INSTANCEOF, $1, $3); }
951	|	'(' expr ')' { $$ = $2; }
952	|	new_expr { $$ = $1; }
953	|	expr '?' expr ':' expr
954			{ $$ = zend_ast_create(ZEND_AST_CONDITIONAL, $1, $3, $5); }
955	|	expr '?' ':' expr
956			{ $$ = zend_ast_create(ZEND_AST_CONDITIONAL, $1, NULL, $4); }
957	|	expr T_COALESCE expr
958			{ $$ = zend_ast_create(ZEND_AST_COALESCE, $1, $3); }
959	|	internal_functions_in_yacc { $$ = $1; }
960	|	T_INT_CAST expr		{ $$ = zend_ast_create_cast(IS_LONG, $2); }
961	|	T_DOUBLE_CAST expr	{ $$ = zend_ast_create_cast(IS_DOUBLE, $2); }
962	|	T_STRING_CAST expr	{ $$ = zend_ast_create_cast(IS_STRING, $2); }
963	|	T_ARRAY_CAST expr	{ $$ = zend_ast_create_cast(IS_ARRAY, $2); }
964	|	T_OBJECT_CAST expr	{ $$ = zend_ast_create_cast(IS_OBJECT, $2); }
965	|	T_BOOL_CAST expr	{ $$ = zend_ast_create_cast(_IS_BOOL, $2); }
966	|	T_UNSET_CAST expr	{ $$ = zend_ast_create_cast(IS_NULL, $2); }
967	|	T_EXIT exit_expr	{ $$ = zend_ast_create(ZEND_AST_EXIT, $2); }
968	|	'@' expr			{ $$ = zend_ast_create(ZEND_AST_SILENCE, $2); }
969	|	scalar { $$ = $1; }
970	|	'`' backticks_expr '`' { $$ = zend_ast_create(ZEND_AST_SHELL_EXEC, $2); }
971	|	T_PRINT expr { $$ = zend_ast_create(ZEND_AST_PRINT, $2); }
972	|	T_YIELD { $$ = zend_ast_create(ZEND_AST_YIELD, NULL, NULL); CG(extra_fn_flags) |= ZEND_ACC_GENERATOR; }
973	|	T_YIELD expr { $$ = zend_ast_create(ZEND_AST_YIELD, $2, NULL); CG(extra_fn_flags) |= ZEND_ACC_GENERATOR; }
974	|	T_YIELD expr T_DOUBLE_ARROW expr { $$ = zend_ast_create(ZEND_AST_YIELD, $4, $2); CG(extra_fn_flags) |= ZEND_ACC_GENERATOR; }
975	|	T_YIELD_FROM expr { $$ = zend_ast_create(ZEND_AST_YIELD_FROM, $2); CG(extra_fn_flags) |= ZEND_ACC_GENERATOR; }
976	|	function returns_ref backup_doc_comment '(' parameter_list ')' lexical_vars return_type
977		backup_fn_flags '{' inner_statement_list '}' backup_fn_flags
978			{ $$ = zend_ast_create_decl(ZEND_AST_CLOSURE, $2 | $13, $1, $3,
979				  zend_string_init("{closure}", sizeof("{closure}") - 1, 0),
980			      $5, $7, $11, $8); CG(extra_fn_flags) = $9; }
981	|	T_STATIC function returns_ref backup_doc_comment '(' parameter_list ')' lexical_vars
982		return_type backup_fn_flags '{' inner_statement_list '}' backup_fn_flags
983			{ $$ = zend_ast_create_decl(ZEND_AST_CLOSURE, $3 | $14 | ZEND_ACC_STATIC, $2, $4,
984			      zend_string_init("{closure}", sizeof("{closure}") - 1, 0),
985			      $6, $8, $12, $9); CG(extra_fn_flags) = $10; }
986;
987
988function:
989	T_FUNCTION { $$ = CG(zend_lineno); }
990;
991
992backup_doc_comment:
993	/* empty */ { $$ = CG(doc_comment); CG(doc_comment) = NULL; }
994;
995
996backup_fn_flags:
997	/* empty */ { $$ = CG(extra_fn_flags); CG(extra_fn_flags) = 0; }
998;
999
1000returns_ref:
1001		/* empty */	{ $$ = 0; }
1002	|	'&'			{ $$ = ZEND_ACC_RETURN_REFERENCE; }
1003;
1004
1005lexical_vars:
1006		/* empty */ { $$ = NULL; }
1007	|	T_USE '(' lexical_var_list ')' { $$ = $3; }
1008;
1009
1010lexical_var_list:
1011		lexical_var_list ',' lexical_var { $$ = zend_ast_list_add($1, $3); }
1012	|	lexical_var { $$ = zend_ast_create_list(1, ZEND_AST_CLOSURE_USES, $1); }
1013;
1014
1015lexical_var:
1016		T_VARIABLE		{ $$ = $1; }
1017	|	'&' T_VARIABLE	{ $$ = $2; $$->attr = 1; }
1018;
1019
1020function_call:
1021		name argument_list
1022			{ $$ = zend_ast_create(ZEND_AST_CALL, $1, $2); }
1023	|	class_name T_PAAMAYIM_NEKUDOTAYIM member_name argument_list
1024			{ $$ = zend_ast_create(ZEND_AST_STATIC_CALL, $1, $3, $4); }
1025	|	variable_class_name T_PAAMAYIM_NEKUDOTAYIM member_name argument_list
1026			{ $$ = zend_ast_create(ZEND_AST_STATIC_CALL, $1, $3, $4); }
1027	|	callable_expr argument_list
1028			{ $$ = zend_ast_create(ZEND_AST_CALL, $1, $2); }
1029;
1030
1031class_name:
1032		T_STATIC
1033			{ zval zv; ZVAL_INTERNED_STR(&zv, CG(known_strings)[ZEND_STR_STATIC]);
1034			  $$ = zend_ast_create_zval_ex(&zv, ZEND_NAME_NOT_FQ); }
1035	|	name { $$ = $1; }
1036;
1037
1038class_name_reference:
1039		class_name		{ $$ = $1; }
1040	|	new_variable	{ $$ = $1; }
1041;
1042
1043exit_expr:
1044		/* empty */				{ $$ = NULL; }
1045	|	'(' optional_expr ')'	{ $$ = $2; }
1046;
1047
1048backticks_expr:
1049		/* empty */
1050			{ $$ = zend_ast_create_zval_from_str(ZSTR_EMPTY_ALLOC()); }
1051	|	T_ENCAPSED_AND_WHITESPACE { $$ = $1; }
1052	|	encaps_list { $$ = $1; }
1053;
1054
1055
1056ctor_arguments:
1057		/* empty */	{ $$ = zend_ast_create_list(0, ZEND_AST_ARG_LIST); }
1058	|	argument_list { $$ = $1; }
1059;
1060
1061
1062dereferencable_scalar:
1063		T_ARRAY '(' array_pair_list ')'	{ $$ = $3; }
1064	|	'[' array_pair_list ']'			{ $$ = $2; }
1065	|	T_CONSTANT_ENCAPSED_STRING		{ $$ = $1; }
1066;
1067
1068scalar:
1069		T_LNUMBER 	{ $$ = $1; }
1070	|	T_DNUMBER 	{ $$ = $1; }
1071	|	T_LINE 		{ $$ = zend_ast_create_ex(ZEND_AST_MAGIC_CONST, T_LINE); }
1072	|	T_FILE 		{ $$ = zend_ast_create_ex(ZEND_AST_MAGIC_CONST, T_FILE); }
1073	|	T_DIR   	{ $$ = zend_ast_create_ex(ZEND_AST_MAGIC_CONST, T_DIR); }
1074	|	T_TRAIT_C	{ $$ = zend_ast_create_ex(ZEND_AST_MAGIC_CONST, T_TRAIT_C); }
1075	|	T_METHOD_C	{ $$ = zend_ast_create_ex(ZEND_AST_MAGIC_CONST, T_METHOD_C); }
1076	|	T_FUNC_C	{ $$ = zend_ast_create_ex(ZEND_AST_MAGIC_CONST, T_FUNC_C); }
1077	|	T_NS_C		{ $$ = zend_ast_create_ex(ZEND_AST_MAGIC_CONST, T_NS_C); }
1078	|	T_CLASS_C	{ $$ = zend_ast_create_ex(ZEND_AST_MAGIC_CONST, T_CLASS_C); }
1079	|	T_START_HEREDOC T_ENCAPSED_AND_WHITESPACE T_END_HEREDOC { $$ = $2; }
1080	|	T_START_HEREDOC T_END_HEREDOC
1081			{ $$ = zend_ast_create_zval_from_str(ZSTR_EMPTY_ALLOC()); }
1082	|	'"' encaps_list '"' 	{ $$ = $2; }
1083	|	T_START_HEREDOC encaps_list T_END_HEREDOC { $$ = $2; }
1084	|	dereferencable_scalar	{ $$ = $1; }
1085	|	constant			{ $$ = $1; }
1086;
1087
1088constant:
1089		name { $$ = zend_ast_create(ZEND_AST_CONST, $1); }
1090	|	class_name T_PAAMAYIM_NEKUDOTAYIM identifier
1091			{ $$ = zend_ast_create(ZEND_AST_CLASS_CONST, $1, $3); }
1092	|	variable_class_name T_PAAMAYIM_NEKUDOTAYIM identifier
1093			{ $$ = zend_ast_create(ZEND_AST_CLASS_CONST, $1, $3); }
1094;
1095
1096expr:
1097		variable					{ $$ = $1; }
1098	|	expr_without_variable		{ $$ = $1; }
1099;
1100
1101optional_expr:
1102		/* empty */	{ $$ = NULL; }
1103	|	expr		{ $$ = $1; }
1104;
1105
1106variable_class_name:
1107	dereferencable { $$ = $1; }
1108;
1109
1110dereferencable:
1111		variable				{ $$ = $1; }
1112	|	'(' expr ')'			{ $$ = $2; }
1113	|	dereferencable_scalar	{ $$ = $1; }
1114;
1115
1116callable_expr:
1117		callable_variable		{ $$ = $1; }
1118	|	'(' expr ')'			{ $$ = $2; }
1119	|	dereferencable_scalar	{ $$ = $1; }
1120;
1121
1122callable_variable:
1123		simple_variable
1124			{ $$ = zend_ast_create(ZEND_AST_VAR, $1); }
1125	|	dereferencable '[' optional_expr ']'
1126			{ $$ = zend_ast_create(ZEND_AST_DIM, $1, $3); }
1127	|	constant '[' optional_expr ']'
1128			{ $$ = zend_ast_create(ZEND_AST_DIM, $1, $3); }
1129	|	dereferencable '{' expr '}'
1130			{ $$ = zend_ast_create(ZEND_AST_DIM, $1, $3); }
1131	|	dereferencable T_OBJECT_OPERATOR property_name argument_list
1132			{ $$ = zend_ast_create(ZEND_AST_METHOD_CALL, $1, $3, $4); }
1133	|	function_call { $$ = $1; }
1134;
1135
1136variable:
1137		callable_variable
1138			{ $$ = $1; }
1139	|	static_member
1140			{ $$ = $1; }
1141	|	dereferencable T_OBJECT_OPERATOR property_name
1142			{ $$ = zend_ast_create(ZEND_AST_PROP, $1, $3); }
1143;
1144
1145simple_variable:
1146		T_VARIABLE			{ $$ = $1; }
1147	|	'$' '{' expr '}'	{ $$ = $3; }
1148	|	'$' simple_variable	{ $$ = zend_ast_create(ZEND_AST_VAR, $2); }
1149;
1150
1151static_member:
1152		class_name T_PAAMAYIM_NEKUDOTAYIM simple_variable
1153			{ $$ = zend_ast_create(ZEND_AST_STATIC_PROP, $1, $3); }
1154	|	variable_class_name T_PAAMAYIM_NEKUDOTAYIM simple_variable
1155			{ $$ = zend_ast_create(ZEND_AST_STATIC_PROP, $1, $3); }
1156;
1157
1158new_variable:
1159		simple_variable
1160			{ $$ = zend_ast_create(ZEND_AST_VAR, $1); }
1161	|	new_variable '[' optional_expr ']'
1162			{ $$ = zend_ast_create(ZEND_AST_DIM, $1, $3); }
1163	|	new_variable '{' expr '}'
1164			{ $$ = zend_ast_create(ZEND_AST_DIM, $1, $3); }
1165	|	new_variable T_OBJECT_OPERATOR property_name
1166			{ $$ = zend_ast_create(ZEND_AST_PROP, $1, $3); }
1167	|	class_name T_PAAMAYIM_NEKUDOTAYIM simple_variable
1168			{ $$ = zend_ast_create(ZEND_AST_STATIC_PROP, $1, $3); }
1169	|	new_variable T_PAAMAYIM_NEKUDOTAYIM simple_variable
1170			{ $$ = zend_ast_create(ZEND_AST_STATIC_PROP, $1, $3); }
1171;
1172
1173member_name:
1174		identifier { $$ = $1; }
1175	|	'{' expr '}'	{ $$ = $2; }
1176	|	simple_variable	{ $$ = zend_ast_create(ZEND_AST_VAR, $1); }
1177;
1178
1179property_name:
1180		T_STRING { $$ = $1; }
1181	|	'{' expr '}'	{ $$ = $2; }
1182	|	simple_variable	{ $$ = zend_ast_create(ZEND_AST_VAR, $1); }
1183;
1184
1185array_pair_list:
1186		/* empty */ { $$ = zend_ast_create_list(0, ZEND_AST_ARRAY); }
1187	|	non_empty_array_pair_list { /* allow single trailing comma */ zend_ast_list *list = zend_ast_get_list($$ = $1); if (list->child[list->children - 1] == NULL) { list->children--; } }
1188;
1189
1190non_empty_array_pair_list:
1191		non_empty_array_pair_list ',' array_pair
1192			{ $$ = zend_ast_list_add($1, $3); }
1193	|	array_pair
1194			{ $$ = zend_ast_create_list(1, ZEND_AST_ARRAY, $1); }
1195	|	non_empty_array_pair_list ',' /* empty, for LHS array lists */
1196			{ $$ = zend_ast_list_add($1, NULL); }
1197	|	','
1198			{ $$ = zend_ast_create_list(1, ZEND_AST_ARRAY, NULL); }
1199	|	',' array_pair
1200			{ $$ = zend_ast_create_list(2, ZEND_AST_ARRAY, NULL, $2); }
1201;
1202
1203array_pair:
1204		expr T_DOUBLE_ARROW expr
1205			{ $$ = zend_ast_create(ZEND_AST_ARRAY_ELEM, $3, $1); }
1206	|	expr
1207			{ $$ = zend_ast_create(ZEND_AST_ARRAY_ELEM, $1, NULL); }
1208	|	expr T_DOUBLE_ARROW '&' variable
1209			{ $$ = zend_ast_create_ex(ZEND_AST_ARRAY_ELEM, 1, $4, $1); }
1210	|	'&' variable
1211			{ $$ = zend_ast_create_ex(ZEND_AST_ARRAY_ELEM, 1, $2, NULL); }
1212	|	expr T_DOUBLE_ARROW T_LIST '(' array_pair_list ')'
1213			{ $5->attr = 1; $$ = zend_ast_create(ZEND_AST_ARRAY_ELEM, $5, $1); }
1214	|	T_LIST '(' array_pair_list ')'
1215			{ $3->attr = 1; $$ = zend_ast_create(ZEND_AST_ARRAY_ELEM, $3, NULL); }
1216;
1217
1218encaps_list:
1219		encaps_list encaps_var
1220			{ $$ = zend_ast_list_add($1, $2); }
1221	|	encaps_list T_ENCAPSED_AND_WHITESPACE
1222			{ $$ = zend_ast_list_add($1, $2); }
1223	|	encaps_var
1224			{ $$ = zend_ast_create_list(1, ZEND_AST_ENCAPS_LIST, $1); }
1225	|	T_ENCAPSED_AND_WHITESPACE encaps_var
1226			{ $$ = zend_ast_create_list(2, ZEND_AST_ENCAPS_LIST, $1, $2); }
1227;
1228
1229encaps_var:
1230		T_VARIABLE
1231			{ $$ = zend_ast_create(ZEND_AST_VAR, $1); }
1232	|	T_VARIABLE '[' encaps_var_offset ']'
1233			{ $$ = zend_ast_create(ZEND_AST_DIM,
1234			      zend_ast_create(ZEND_AST_VAR, $1), $3); }
1235	|	T_VARIABLE T_OBJECT_OPERATOR T_STRING
1236			{ $$ = zend_ast_create(ZEND_AST_PROP,
1237			      zend_ast_create(ZEND_AST_VAR, $1), $3); }
1238	|	T_DOLLAR_OPEN_CURLY_BRACES expr '}'
1239			{ $$ = zend_ast_create(ZEND_AST_VAR, $2); }
1240	|	T_DOLLAR_OPEN_CURLY_BRACES T_STRING_VARNAME '}'
1241			{ $$ = zend_ast_create(ZEND_AST_VAR, $2); }
1242	|	T_DOLLAR_OPEN_CURLY_BRACES T_STRING_VARNAME '[' expr ']' '}'
1243			{ $$ = zend_ast_create(ZEND_AST_DIM,
1244			      zend_ast_create(ZEND_AST_VAR, $2), $4); }
1245	|	T_CURLY_OPEN variable '}' { $$ = $2; }
1246;
1247
1248encaps_var_offset:
1249		T_STRING		{ $$ = $1; }
1250	|	T_NUM_STRING	{ $$ = $1; }
1251	|	T_VARIABLE		{ $$ = zend_ast_create(ZEND_AST_VAR, $1); }
1252;
1253
1254
1255internal_functions_in_yacc:
1256		T_ISSET '(' isset_variables ')' { $$ = $3; }
1257	|	T_EMPTY '(' expr ')' { $$ = zend_ast_create(ZEND_AST_EMPTY, $3); }
1258	|	T_INCLUDE expr
1259			{ $$ = zend_ast_create_ex(ZEND_AST_INCLUDE_OR_EVAL, ZEND_INCLUDE, $2); }
1260	|	T_INCLUDE_ONCE expr
1261			{ $$ = zend_ast_create_ex(ZEND_AST_INCLUDE_OR_EVAL, ZEND_INCLUDE_ONCE, $2); }
1262	|	T_EVAL '(' expr ')'
1263			{ $$ = zend_ast_create_ex(ZEND_AST_INCLUDE_OR_EVAL, ZEND_EVAL, $3); }
1264	|	T_REQUIRE expr
1265			{ $$ = zend_ast_create_ex(ZEND_AST_INCLUDE_OR_EVAL, ZEND_REQUIRE, $2); }
1266	|	T_REQUIRE_ONCE expr
1267			{ $$ = zend_ast_create_ex(ZEND_AST_INCLUDE_OR_EVAL, ZEND_REQUIRE_ONCE, $2); }
1268;
1269
1270isset_variables:
1271		isset_variable { $$ = $1; }
1272	|	isset_variables ',' isset_variable
1273			{ $$ = zend_ast_create(ZEND_AST_AND, $1, $3); }
1274;
1275
1276isset_variable:
1277		expr { $$ = zend_ast_create(ZEND_AST_ISSET, $1); }
1278;
1279
1280%%
1281
1282/* Copy to YYRES the contents of YYSTR after stripping away unnecessary
1283   quotes and backslashes, so that it's suitable for yyerror.  The
1284   heuristic is that double-quoting is unnecessary unless the string
1285   contains an apostrophe, a comma, or backslash (other than
1286   backslash-backslash).  YYSTR is taken from yytname.  If YYRES is
1287   null, do not copy; instead, return the length of what the result
1288   would have been.  */
1289static YYSIZE_T zend_yytnamerr(char *yyres, const char *yystr)
1290{
1291	/* CG(parse_error) states:
1292	 * 0 => yyres = NULL, yystr is the unexpected token
1293	 * 1 => yyres = NULL, yystr is one of the expected tokens
1294	 * 2 => yyres != NULL, yystr is the unexpected token
1295	 * 3 => yyres != NULL, yystr is one of the expected tokens
1296	 */
1297	if (yyres && CG(parse_error) < 2) {
1298		CG(parse_error) = 2;
1299	}
1300
1301	if (CG(parse_error) % 2 == 0) {
1302		/* The unexpected token */
1303		char buffer[120];
1304		const unsigned char *end, *str, *tok1 = NULL, *tok2 = NULL;
1305		unsigned int len = 0, toklen = 0, yystr_len;
1306
1307		CG(parse_error)++;
1308
1309		if (LANG_SCNG(yy_text)[0] == 0 &&
1310			LANG_SCNG(yy_leng) == 1 &&
1311			memcmp(yystr, "\"end of file\"", sizeof("\"end of file\"") - 1) == 0) {
1312			if (yyres) {
1313				yystpcpy(yyres, "end of file");
1314			}
1315			return sizeof("end of file")-1;
1316		}
1317
1318		str = LANG_SCNG(yy_text);
1319		end = memchr(str, '\n', LANG_SCNG(yy_leng));
1320		yystr_len = (unsigned int)yystrlen(yystr);
1321
1322		if ((tok1 = memchr(yystr, '(', yystr_len)) != NULL
1323			&& (tok2 = zend_memrchr(yystr, ')', yystr_len)) != NULL) {
1324			toklen = (tok2 - tok1) + 1;
1325		} else {
1326			tok1 = tok2 = NULL;
1327			toklen = 0;
1328		}
1329
1330		if (end == NULL) {
1331			len = LANG_SCNG(yy_leng) > 30 ? 30 : LANG_SCNG(yy_leng);
1332		} else {
1333			len = (end - str) > 30 ? 30 : (end - str);
1334		}
1335		if (yyres) {
1336			if (toklen) {
1337				snprintf(buffer, sizeof(buffer), "'%.*s' %.*s", len, str, toklen, tok1);
1338			} else {
1339				snprintf(buffer, sizeof(buffer), "'%.*s'", len, str);
1340			}
1341			yystpcpy(yyres, buffer);
1342		}
1343		return len + (toklen ? toklen + 1 : 0) + 2;
1344	}
1345
1346	/* One of the expected tokens */
1347	if (!yyres) {
1348		return yystrlen(yystr) - (*yystr == '"' ? 2 : 0);
1349	}
1350
1351	if (*yystr == '"') {
1352		YYSIZE_T yyn = 0;
1353		const char *yyp = yystr;
1354
1355		for (; *++yyp != '"'; ++yyn) {
1356			yyres[yyn] = *yyp;
1357		}
1358		yyres[yyn] = '\0';
1359		return yyn;
1360	}
1361	yystpcpy(yyres, yystr);
1362	return strlen(yystr);
1363}
1364
1365/*
1366 * Local variables:
1367 * tab-width: 4
1368 * c-basic-offset: 4
1369 * indent-tabs-mode: t
1370 * End:
1371 */
1372